From 26ff8cad89efd15f6f0631ad10245eae06883af9 Mon Sep 17 00:00:00 2001
From: Kurtis Andrews <kurtis@whonet.com.au>
Date: Fri, 5 Feb 2021 20:52:48 +1000
Subject: [PATCH] Initial Commit initial script upload. Need to change this to
 a system tray icon.

---
 README.md           |  0
 alt-tab-disable.au3 | 43 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 43 insertions(+)
 create mode 100644 README.md
 create mode 100644 alt-tab-disable.au3

diff --git a/README.md b/README.md
new file mode 100644
index 0000000..e69de29
diff --git a/alt-tab-disable.au3 b/alt-tab-disable.au3
new file mode 100644
index 0000000..53e5abf
--- /dev/null
+++ b/alt-tab-disable.au3
@@ -0,0 +1,43 @@
+#include <WinAPI.au3>
+#include <WindowsConstants.au3>
+#include <StructureConstants.au3>
+
+HotKeySet("{Pause}", "_Exit")
+
+Global Const $VK_TAB = 0x09
+
+$hHookProc = DllCallbackRegister("_KeyboardProc", "long", "int;wparam;lparam")
+
+$hHookKeyboard = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($hHookProc), _WinAPI_GetModuleHandle(0), 0)
+
+While 1
+    Sleep(100)
+WEnd
+
+Func _KeyboardProc($nCode, $wParam, $lParam)
+    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($hHookKeyboard, $nCode, $wParam, $lParam)
+    
+    Switch $wParam
+        Case $WM_KEYDOWN, $WM_SYSKEYDOWN, $WM_KEYUP, $WM_SYSKEYUP
+            Local $tKEYHOOKS = DllStructCreate($tagKBDLLHOOKSTRUCT, $lParam)
+            Local $vKode = DllStructGetData($tKEYHOOKS, "vkCode")
+            Local $iFlags = DllStructGetData($tKEYHOOKS, "flags")
+            
+            Switch $vKode
+                Case $VK_TAB
+                    If BitAND($iFlags, $LLKHF_ALTDOWN) Then
+                        Return -1
+                    Else
+                        Return _WinAPI_CallNextHookEx($hHookKeyboard, $nCode, $wParam, $lParam)
+                    EndIf
+            EndSwitch
+    EndSwitch
+    
+    Return _WinAPI_CallNextHookEx($hHookKeyboard, $nCode, $wParam, $lParam)
+EndFunc   ;==>_KeyboardProc
+
+Func _Exit()
+    DllCallbackFree($hHookProc)
+    _WinAPI_UnhookWindowsHookEx($hHookKeyboard)
+    Exit
+EndFunc
\ No newline at end of file